シート上の数式マクロをVBAで復活させるアイデア

数式マクロを復活させるアイデア
テスト用シート
プログラム解説
使い方
まとめ
1. 関連記事:

数式マクロを復活させるアイデア

　セルに入力した数式マクロは、間違って値を直接入力してしまうと上書きされてしまい、数式マクロは失われてしまいます。
　すぐに復活できるようなマクロであれば問題ありませんが、複雑なマクロの場合作り直すのが大変です。

　バックアップを取っておくのがセオリーですが、シート内にある各セルの数式マクロをVBAのコードとして取っておくのも一つのアイデアです。

ActiveSheet.Cells(8, 7).Formula = "=SUM(G6:G7)"

という感じですね！
ただ、あちこちに数式マクロがある場合、それらの場所と数式を上記のように書くのは面倒です。

　そこで、VBAでシート上にあるすべての数式マクロを読み込んで、Debug.Print でイミディエイトウィンドウに表示させる事にします。
　ただ表示させるだけでなく、そのままコピーすればプロシージャとして使えるように出力し、イミディエイトウィンドウから標準モジュールにコピーすれば使えるようにプロシージャの形で出力するようにしました。

テスト用シート

　今回は上記のようなシートを用意しました。黄色のセルには数式マクロが入っています。
青の吹き出しが数式マクロです。

プログラム解説

'数式マクロを復活させるためのプログラムコードをイミディエイトウィンドウに表示させます。
'プログラムコードをコピーして、Moduleに貼り付けて使用します。
Sub ReFormulaMakeCode()
    
    Dim r As Range
    Dim befor As Range
    Dim cnt As Long
    Dim rc As Integer
    Dim es As String
    Dim MySheetName As String
    
    Set befor = Selection
    
    Set r = ActiveSheet.UsedRange ' 使用しているセルの範囲を取得
    r.Select
    
    MySheetName = ActiveSheet.Name
    
    Debug.Print "Sub 数式マクロを復活_" & MySheetName & "()"
    Debug.Print "    With Worksheets(""" & MySheetName & """)"
    
    cnt = 0
    For Each r In Selection
       If r.HasFormula Then
           es = Replace(r.Formula, """", """""")
           es = """" & es & """"
           Debug.Print "    .Cells(" & r.Row & "," & r.Column & ").Formula=" & es
       End If
       
       '処理が長くなってしまった時に終了できるようにする。
       If cnt Mod 1000000 = 99999 Then
           rc = MsgBox("処理を続けますか？", vbYesNo + vbQuestion, "確認")
           If rc = vbYes Then
           Else
               MsgBox "終了します。"
               Exit For
           End If
       End If
      
       cnt = cnt + 1
    Next r
     
    Debug.Print "    End With"
    Debug.Print "End Sub"
     
    befor.Select
End Sub